Calling multiple methods from one RemoteObject in Flex and Actionscript using BlazeDS

Nick — Wed, 19 Aug 2009 20:22:36 +0000

BlazeDS allows us to use RPC to access our Java objects from an Adobe Flex or AIR app. This is a simple example that allows you to have a remote java object which you will make calls upon from Flex (or Actionscript). There are plenty of BlazeDS remoting tutorials out there. This HOW-TO shows how to create an actionscript class to handle your remote objects and handlers as well as linking more than one method to a single remote object.

This HOW-TO assumes you have the knowledge to create a small flex app and a server-side java project using BlazeDS. If you don’t know how to do this, there are tons of tutorials out there like this one.

Here’s the java object that we’ll be calling methods on from Flex:

public class MyRemoteService {
	public MyRemoteService() { }
 
	public String getSessionId() {
		String sessionId = FlexContext.getFlexSession().getId();
		System.out.println("returning sessionId "+sessionId);
		return sessionId;
	}
 
	public String[] getMyData() {
		return stuff from database or whatever
	}
}

Our RemoteObject will be called remoteService and will call the two methods getSessionId() and getMyData(). The following is the mxml for remoteService that has the two methods. Each method has a name attribute and attributes to set handlers for a fault and result.

This next code block does the same thing as our above code, except it’s an actionscript class. It handles the same two methods.

public class ConnectionManager
{
	import mx.controls.Alert;
	import mx.rpc.events.FaultEvent; 
	import mx.rpc.AsyncToken;
	import mx.rpc.Responder;
	import mx.rpc.events.ResultEvent;
	import mx.rpc.remoting.mxml.RemoteObject;
	import mx.messaging.Channel; 
	import mx.messaging.ChannelSet; 
	import mx.messaging.channels.AMFChannel;  
 
	private var blazeUrl:String = "http://localhost:8080/BlazeServer/messagebroker/";
	private var remoteService:RemoteObject = new RemoteObject;
 
	public function ConnectionManager()
	{
		var cs:ChannelSet = new ChannelSet(); 
		var myAMF:Channel = new AMFChannel("my-amf", blazeUrl + "amf"); 
		cs.addChannel(myAMF); 
		remoteService.channelSet = cs; 
 
		remoteService.destination = "remoteServiceDestination";
		remoteService.showBusyCursor = true;
		var rpcCall:AsyncToken;
 
		rpcCall = remoteService.getSessionId();
		rpcCall.addResponder(new Responder(handler_getSessionIdSuccess, handler_getSessionIdFault) );
 
		rpcCall = remoteService.getMyData();
		rpcCall.addResponder(new Responder(handler_getMyDataSuccess, handler_getMyDataFault) );
	}
 
	private function handler_getSessionIdSuccess(event:ResultEvent):void {
		trace(event);
		Alert.show("sessionId: "+event.message.body.toString(), "handler_getSessionIdSuccess");
	}
 
	private function handler_getSessionIdFault(fault:FaultEvent):void {
		trace(fault);
		Alert.show(fault.toString(), "handler_getSessionIdFault");
	}
 
	private function handler_getMyDataSuccess(event:ResultEvent):void {
		trace(event);
		Alert.show(event.message.body.toString(), "handler_getMyDataSuccess");
	}
 
	private function handler_getMyDataFault(fault:FaultEvent):void {
		trace(fault);
		Alert.show(fault.toString(), "handler_getMyDataFault");
	}
}

For a good book about Flex check out Flex 3 in Action

Looping Sound in Flex and AIR

Nick — Mon, 27 Jul 2009 20:10:48 +0000

This is a short example of how to play an audio clip and loop it in Flex, and works with AIR. Some of this code is taken from the Sound class example in the Adobe Flex Language Reference docs.

You can paste this into pretty much any function, like an init():

var soundReq:URLRequest = new URLRequest("someSound.mp3"); 
var sound:Sound = new Sound(); 
var soundControl:SoundChannel = new SoundChannel(); 
sound.addEventListener(Event.COMPLETE, completeHandler);
sound.addEventListener(Event.ID3, id3Handler);
sound.addEventListener(IOErrorEvent.IO_ERROR, ioSoundErrorHandler);
sound.addEventListener(ProgressEvent.PROGRESS, progressHandler);
sound.load(soundReq); 
soundControl = sound.play(0, int.MAX_VALUE);

Notice the line:
sound.play(0, int.MAX_VALUE);
The second parameter is the number of times to loop. Set it to zero to play the sound one time. There’s no real way (that I have found) to play the audio infinite times, so I put in int.MAX_VALUE which is a 32-bit signed integer of the value 2,147,483,647. Sure this won’t loop forever, but given a one second audio clip it would loop for about 68 years!

Here’s the handlers to go along with it:

private function completeHandler(event:Event):void {
    trace("completeHandler: " + event);
}
 
private function ioSoundErrorHandler(event:Event):void {
    trace("ioSoundErrorHandler: " + event);
}
 
private function id3Handler(event:Event):void {
    trace("id3Handler: " + event);
}
 
private function progressHandler(event:ProgressEvent):void {
    trace("progressHandler: " + event);
}

I’m still new to Flex so if anyone notices anything that isn’t right, please let me know. Also if anyone is looking for a decent BlazeDS tutorial, I’ve found one here. Also been reading Programming Flex 3: The Comprehensive Guide to Creating Rich Internet Applications with Adobe Flex which isn’t bad, if anyone else recommends a book let me know.

/home/nick » Flex

Calling multiple methods from one RemoteObject in Flex and Actionscript using BlazeDS

Looping Sound in Flex and AIR